用VBScript实现的快速排序的算法

自：http://www.cnblogs.com/falconshh/archive/2011/05/30/2063204.html

写了个用VBScript实现的快速排序的算法

该算法参考的严蔚敏老师97版 C语言版的快排算法（没有做枢轴的优化）,使用了递归调用的方式。

代码经调试运行无误(控制台程序)。

按 Ctrl+C 复制代码

Dim arr
 Dim low
Dim high
arr = Array(1,99,58.32,8,7,3,4.18,2,6,14,65,9,23,43,78,9)

low = Lbound(arr)
high = Ubound(arr)

'===调用快速排序===
QuickSort arr,low,high

For i = 0 to Ubound(arr)
    Response.Write(arr(i)&"&nbsp;&nbsp;")
Next

'===========用VBScript实现快速排序======开始============
'Author:falconshh 2011.05.30
'arr:待排数组，下标从0....n-1
'low:数组最低端下标
'high:数组最高端下标
Sub QuickSort(arr,low,high)
    Dim pivotPos '枢轴位置
    If low < high Then
        pivotPos = CInt(Partition(arr,low,high))
        QuickSort arr,low,pivotPos-1  '对低端子数组排序
        QuickSort arr,pivotPos+1,high '对高端子数组排序
    End if
End Sub

'分割数据
Function Partition(arr,low,high)
    Dim pivot '定义枢轴
    pivot = arr(low) '取第一个记录作为枢轴
    i = low
    j = high
    
    Do While (i < j)
        Do While (i < j and arr(j) >= pivot)
            j = j - 1            
        Loop
        
        arr(i) = arr(j) '将枢轴移到低端
        
        Do While (i < j and arr(i) <= pivot)
            i = i + 1
        Loop
        arr(j) = arr(i) '将枢轴移到高端
    Loop
    
    arr(i) = pivot '将枢轴放置到正确的位置(中间点)
    Partition = i '返回枢轴的位置
End Function
'===========用VBScript实现快速排序======结束============

按 Ctrl+C 复制代码

排序结果如下：

1 2 3 4.18 6 7 8 9 9 14 23 43 58.32 65 78 99

点击复制内容点击运行代码